*******************************************************************
******STMicroelectronics MOSFET, IGBT and Bipolar Library *********
*******************************************************************
*								*
* Models provided by STMicroelectronics are not guaranteed to	*
* fully represent all the specifications and operating		*
* characteristics of the product behavior that they reproduce.	*
* The model describes the characteristics of a typical device.	*
* In all cases, the current product data sheet contains all	*
* information to be used like final design guidelines and the	*
* only actual performance specification.			*
* Altough models can be a useful tool in evaluating device	*
* performance, they cannot model exact device performance under	*
* all conditions.						*
* STMicroelectronics therefore does not assume any		*
* responsibility arising from their use.			*
* STMicroelectronics reserves the right to change models	*
* without prior notice.						*
*								*
* Note: The model doesn't take into account the drain, gate,	*
* source inductances.If these contributions have to be		*
* considered it is possible include the inductors externally.	*
* For this package the values can be estimated as follow	*
*								*
* Ldrain= 1nH ,Lsource=2nH and Lgate=2.5nH			*
*								*
* Rev 2.0 - 10 April 2013		      			*
*******************************************************************

.SUBCKT STL3N10F7_V2 1 2 3
*******************************************************************
E1 Tj val_T VALUE={TEMP}
R1 val_T 0 1E-03
***********************************************************
Rtk Tj 0 1E10
Rtk1 Tj 0 1E10
************************************
VLd 1 d1k 0
VLs ss 3 0
VLG 2 g2 0
rg1 g2 g {rg}
Rdsx s dx 100k
Cdx dx d 50p
*******************************************************************
.PARAM Area=1 BVDSS=1 raval=121m
***************************************************
.PARAM  rg=1.85 Vth0=4 drs=10u
.PARAM  lambda=0.001 
.PARAM  kpsat0=3.3 kplin0=20 


.PARAM  rd=53.6m 
.PARAM  rpa=1E-05

***********************************
.PARAM  unt =-1.8 vthx=4.5m ksat=-1 klin=-1
.PARAM  a=1 b=1 Rx=1.1
.param  rr=1 


***********************************************************
.FUNC r_s(T) {drs*((T+273)/300)**(rr)}
.FUNC vth1(x) {vth0-vthx*(x-27)}
.FUNC kpsat(x) {kpsat0*((x+273)/300)**(ksat)}
.FUNC kplin(x) {kplin0*((x+273)/300)**(klin)}
.FUNC un(T) {b*((T+273)/300)**(unt)}

***********************************************************
***********************************************************
Gmos d s value {Area*(IF(V(d,s)>0,(IF(v(g,s)<vth1(V(TJ)),0,
+(IF((V(d,s)<(v(g,s)-vth1(V(TJ)))*kpsat(v(TJ))/kplin(v(TJ))),(1+LAMBDA*v(d,s))*kplin(v(TJ))/2*v(d,s)*
+(2*(v(g,s)-vth1(V(TJ)))-kplin(v(TJ))/kpsat(v(TJ))*v(d,s)),
+(1+LAMBDA*v(d,s))*kpsat(v(TJ))/2*(v(g,s)-vth1(V(TJ)))**2)))),-(IF(v(g,s)<vth1(V(TJ)),0,
+(IF((V(s,d)<(v(g,s)-vth1(V(TJ)))*kpsat(v(TJ))/kplin(v(TJ))),(1+LAMBDA*v(s,d))*kplin(v(TJ))/2*v(s,d)*
+(2*(v(g,s)-vth1(V(TJ)))-kplin(v(TJ))/kpsat(v(TJ))*v(s,d)),
+(1+LAMBDA*v(s,d))*kpsat(v(TJ))/2*(v(g,s)-vth1(V(TJ)))**2))))))} 

G_RMos d1k dd VALUE={Area*((un(V(TJ))*(V(d1k,d)))/(rd+rpa*((I(V_sense)**a))**Rx))}

G_rs s ss VALUE={v(s,ss)/(r_s(V(TJ)))}

R_Grs s ss 1E03
R_Rmos d1k dd 1E03
V_sense dd d 0
***********************************************************
rdd dd 0 1E10
rdd1 d 0 1E10
rdd3 s 0 1E10
R_DS d s 1E10
***********************************************************
CGS g 3  {518p*Area}
R_CGS g 3 500E06
***********************************************************
Cref 40 0 1E-12
E2 40 50 value {V(g,d1k)}
V2 50 0 0
Gcdg d1k g value {Area*V(alfa)*i(V2)*1E12}
Rcap 0 alfa 1E03
Ecap alfa 0 TABLE = {V(d1k,ss)}
+(0.1,231p) 
+(0.2,212p) 
+(0.5,203p) 
+(1,182p) 
+(2,135p) 
+(3,79p) 
+(5,71p) 
+(7,49p) 
+(10,32p) 
+(15,25p) 
+(25,18p) 
+(35,14p) 
+(50,10p) 
+(60,8p) 
+(70,7p) 
+(80,6p) 
+(90,6p) 
+(100,6p) 

***********************************************************
Cref2 402 0 1E-12
E22 402 502 value {V(ss,d1k)}
V22 502 0 0
Gcdg2 d1k ss value {0.5*Area*V(alfa2)*i(V22)*1E12}
Rcap2 0 alfa2 100E03
Ecap2 alfa2 0 TABLE = {V(d1k,ss)}
+(0.1,356p) 
+(0.2,347p) 
+(0.5,321p) 
+(1,292p) 
+(2,261p) 
+(3,243p) 
+(5,222p) 
+(7,208p) 
+(10,193p) 
+(15,175p) 
+(25,152p) 
+(35,135p) 
+(50,112p) 
+(60,94p) 
+(70,66p) 
+(80,52p) 
+(90,47p) 
+(100,44p) 


***********************************************************
***********************************************************
R_bvdss	d1k d1bvdss1 {raval}
V_bvdss	d1bvdss1 d1bvdss2 0
G_bvd	d1bvdss2 ss VALUE={I_BVDSS(V(d1bvdss2,ss),v(Tj))}
R_GBDSS	d1bvdss2 0 1E10
.FUNC I_BVDSS(z,k1) {(exp(min(-175+z/(bvd(k1)),7))-10E-12)}
***********************************************************
.FUNC bvd(k) {0.62*BVDSS+0.00031*k}
***********************************************************
.FUNC Rdiodo(rdid) {rdid0*((rdid+273)/300)**(rdid_temp)}
.PARAM rdid0={1.5/Area} rdid_temp=1.5
G_R_didd d1k d1z VALUE={200*(V(d1k,d1z)/Rdiodo(V(TJ)))}

R_G_R_didd d1k d1z {1/Area}

V_diodo d1zd d1z 0

G_diode 3 d1zd VALUE={I_diode(V(3,d1zd),v(Tj))}
R_x 3 d1zd 1E9

.FUNC I_diode(z3,k3) {(exp(min(-15+z3/(did(k3)),7))-100n)}


.FUNC did(k4) {0.066-91E-06*k4}

***********************************************************
R_R003 aa 0 500E06
R_edep d1k d_dedep 75
E_Eds d_dedep edep VALUE {-V(aa,0)*1k}
C_Cds edep ss {16E-12*Area}
E_E001 ba 0 VALUE {-I(V_diodo)*(0.0016*v(Tj)+1)}
R_R001 aa ba 35
C aa 0 19p
***********************************************************

.ENDS STL3N10F7_V2

* END OF MODELLING